Stop idle environments

default allow := false

organization_id := "REPLACE_WITH_ORGANIZATION_ID"
project_id := "REPLACE_WITH_PROJECT_ID"

# The non-production environments the agent may stop and start.
idle_candidate_environment_ids := {
	"REPLACE_WITH_DEV_ENVIRONMENT_ID",
	"REPLACE_WITH_QA_ENVIRONMENT_ID",
}

allow if cli_lookup
allow if read_candidates
allow if stop_or_start

# Let the Qovery CLI find the organization, project and environment by name.
cli_lookup if {
	input.request.method == "GET"
	input.request.path in {
		["api", "organization"],
		["api", "organization", organization_id],
		["api", "organization", organization_id, "project"],
		["api", "project", project_id],
		["api", "project", project_id, "environment"],
	}
}

# Read the status and deployment history of those environments.
read_candidates if {
	input.request.method in {"GET", "HEAD"}
	input.qovery_metadata.environment_id in idle_candidate_environment_ids
	not "environmentVariable" in input.request.path
}

# Stop an environment, or start it again with a deploy. Nothing else.
stop_or_start if {
	input.request.method == "POST"
	input.request.path[1] == "environment"
	input.request.path[2] in idle_candidate_environment_ids
	input.request.path[3] in {"stop", "deploy"}
	count(input.request.path) == 4
}