Right-size applications

default allow := false

organization_id := "REPLACE_WITH_ORGANIZATION_ID"
project_id := "REPLACE_WITH_PROJECT_ID"
staging_environment_id := "REPLACE_WITH_STAGING_ENVIRONMENT_ID"

# The applications the agent may resize. Instances and branch stay as they are today.
applications := {
	"REPLACE_WITH_API_APPLICATION_ID": {"min_instances": 1, "max_instances": 3, "branch": "main"},
	"REPLACE_WITH_WORKER_APPLICATION_ID": {"min_instances": 1, "max_instances": 2, "branch": "main"},
}

# Bounds for CPU (millicores) and memory (MB).
cpu_bounds := {"min": 100, "max": 2000}
memory_bounds := {"min": 128, "max": 4096}

allow if cli_lookup
allow if read_staging
allow if resize
allow if redeploy

# Let the Qovery CLI find the organization, project and environment by name.
cli_lookup if {
	input.request.method == "GET"
	input.request.path in {
		["api", "organization"],
		["api", "organization", organization_id],
		["api", "organization", organization_id, "project"],
		["api", "project", project_id],
		["api", "project", project_id, "environment"],
	}
}

# Read staging: services, status, deployment history and logs.
read_staging if {
	input.request.method in {"GET", "HEAD"}
	input.qovery_metadata.environment_id == staging_environment_id
	not "environmentVariable" in input.request.path
}

# Change CPU and memory within the bounds. Instances and branch must not change.
resize if {
	input.request.method == "PUT"
	input.request.path[1] == "application"
	count(input.request.path) == 3
	app := applications[input.request.path[2]]
	body := input.request.body
	body.cpu >= cpu_bounds.min
	body.cpu <= cpu_bounds.max
	body.memory >= memory_bounds.min
	body.memory <= memory_bounds.max
	body.min_running_instances == app.min_instances
	body.max_running_instances == app.max_instances
	body.git_repository.branch == app.branch
}

# Redeploy a resized application so the new values apply.
redeploy if {
	input.request.method == "POST"
	input.request.path[1] == "application"
	applications[input.request.path[2]]
	input.request.path[3] == "redeploy"
	count(input.request.path) == 4
}